WIRTUALNY KLUB MODELARZY RC

$regfile = "attiny13.dat"
$crystal = 128000


Dim Timer_glowny As Byte                'licznik 10ms zliczajacy do 2000ms
Dim Licznik_bledy As Byte               'licznik przpelnien 10ms
Dim Poczatek_przerwanie As Byte         'czas na przerwaniu PB1 = 1
Dim Koniec_przerwanie As Byte           'czas na przerwaniu PB1 = 0
Dim Szerokosc_impulsu As Byte           'szerokosc impulsu z odbiornika sprawdzana co przerwanie
Dim Pomoc As Byte                       'zmienna obslugi swiatla ladowania
Dim Flaga As Bit                        'zmienna informujaca czy tryb strobe
Dim Flaga2 As Bit                       'zmienna informujaca czy przerwanie rozpoczynajace


Config Portb = &B111101                 'ustawienie wejsc i wyjsc
Portb = &B011101                        'zapalenie diodek

Waitms 500

Flaga = 1
Flaga2 = 1
Timer0 = 96                             'poczatek odliczania

Config Timer0 = Timer , Prescale = 8    'ustawienie timera skalowanego o 8 razy - 1imp = 62,5us

Config Int0 = Change                    'przerwanie na zmiane stanu PB1

Enable Timer0
Enable Int0
Enable Interrupts
On Timer0 Co10ms
On Int0 Przerwanie_zmiana



Do                                      'glowna petla
  If Timer_glowny >= 200 Then           'sprawdzenie czy minely 2s
    Timer_glowny = 0                    'zerowanie licznika 2s
    Flaga = 0

    If Flaga2 = 0 Then
      If Licznik_bledy < 2 Then         'sprawdzenie czy licznik "przekrecil sie" wiecej niz 1 raz
        If Poczatek_przerwanie > Koniec_przerwanie Then       'sprawdzenie czy koniec impulsu nastapil po "przekreceniu sie" licznika
          Szerokosc_impulsu = 159 + Koniec_przerwanie
          Szerokosc_impulsu = Szerokosc_impulsu - Poczatek_przerwanie
        Else
          Szerokosc_impulsu = Koniec_przerwanie - Poczatek_przerwanie
        End If
      Else
        Szerokosc_impulsu = 0
      End If
    End If

    If Szerokosc_impulsu < 13 Then      'sprawdzenie czy impuls nie jest za krotki < 0,8125ms
      Flaga = 1
    End If
    If Szerokosc_impulsu > 35 Then      'sprawdzenie czy impuls nie jest za dlugi > 2,1875ms
      Flaga = 1
    End If
  End If

  If Licznik_bledy >= 200 Then          'sprawdzenie stanu licznika blednych ramek
    Licznik_bledy = 199                 'przejscie w tryb awaryjny jesli bledne ramki pojawiaja sie od 1s
    Szerokosc_impulsu = 0
  End If


  If Flaga = 0 Then
    If Szerokosc_impulsu < 22 Then      'kanal wysterowany na minimum NAVI-ON. LAND-OFF. BEACON-ON-0s;1s. STROBE-ON-0,3s.
        Pomoc = &B000000
    Else                                'kanal wysterowany na maksimum NAVI-ON. LAND-ON. BEACON-ON-0s;1s. STROBE-ON-0,3s.
        Pomoc = &B001000
    End If
      Select Case Timer_glowny
        Case 0 To 1 : Portb = &B010100 Or Pomoc
        Case 30 To 31 : Portb = &B010001 Or Pomoc
        Case 100 To 101 : Portb = &B010100 Or Pomoc
        Case Else : Portb = &B010000 Or Pomoc
      End Select
  Else                                  'NAVI-ON. LAND-OFF. BEACON-ON-0s;1s. STROBE-ON-0,2s;0,4s.
    Select Case Timer_glowny
      Case 0 To 1 : Portb = &B010100
      Case 20 To 21 : Portb = &B010001
      Case 40 To 41 : Portb = &B010001
      Case 100 To 101 : Portb = &B010100
      Case Else : Portb = &B010000
    End Select
  End If
Loop
End



Co10ms:
Timer0 = 96                             'poczatek odliczania
Incr Timer_glowny                       'zwiekszenie licznika 10ms
Incr Licznik_bledy                      'zwiekszenie wskaznika bledow
Return



Przerwanie_zmiana:
  If Pinb.1 = 1 Then                    'sprawdzenie rodzaju przerwania
    Poczatek_przerwanie = Timer0        'zapamietanie stanu zegara na przerwaniu rozpoczynajacym impuls
    Licznik_bledy = 0                   'zerowanie licznika bledow
    Flaga2 = 1
  Else
    Koniec_przerwanie = Timer0          'zapamietanie stanu zegara na przerwaniu konczacym impuls
    Flaga2 = 0
  End If
Return